ParticleEvent.f90

Go to the documentation of this file.

module particleeventmodule
  use kindmodule, only: dp, i4b, lgp
  use errorutilmodule, only: pstop
  use particlemodule, only: particletype
  implicit none
 
  private
  public :: particleeventtype
  public :: cellexiteventtype, terminationeventtype, releaseeventtype
  public :: timestepeventtype, weaksinkeventtype, usertimeeventtype
  public :: release, cellexit, timestep, terminate, weaksink, usertime
 
  !> @brief Particle event enumeration.
  !!
  !! A number of events may occur to particles, each of which may (or may
  !! not) be of interest to the user. The user selects events to report.
  !<
  enum, bind(C)
    enumerator :: release = 0 !< particle was released
    enumerator :: cellexit = 1 !< particle exited a cell
    enumerator :: timestep = 2 !< time step ended
    enumerator :: terminate = 3 !< particle terminated
    enumerator :: weaksink = 4 !< particle exited a weak sink
    enumerator :: usertime = 5 !< user-specified tracking time
  end enum
 
  !> @brief Base type for particle events.
  !!
  !! Events may be identical except for their type/code, reflecting the
  !! fact that several events of interest may occur at a given moment.
  type, abstract :: particleeventtype
    type(particletype), pointer :: particle => null() ! particle causing the event
    integer(I4B) :: code = -1 ! event code
    integer(I4B) :: kper = 0, kstp = 0 ! period and step
    real(dp) :: time = 0.0_dp ! simulation time
  contains
    procedure :: get_code
    procedure :: get_str
  end type particleeventtype
 
  type, extends(particleeventtype) :: cellexiteventtype
  end type cellexiteventtype
 
  type, extends(particleeventtype) :: terminationeventtype
  end type terminationeventtype
 
  type, extends(particleeventtype) :: releaseeventtype
  end type releaseeventtype
 
  type, extends(particleeventtype) :: timestepeventtype
  end type timestepeventtype
 
  type, extends(particleeventtype) :: weaksinkeventtype
  end type weaksinkeventtype
 
  type, extends(particleeventtype) :: usertimeeventtype
  end type usertimeeventtype
 
contains
  integer function get_code(this) result(code)
    class(particleeventtype), intent(in) :: this
 
    select type (this)
    type is (releaseeventtype); code = 0
    type is (cellexiteventtype); code = 1
    type is (timestepeventtype); code = 2
    type is (terminationeventtype); code = 3
    type is (weaksinkeventtype); code = 4
    type is (usertimeeventtype); code = 5
    class default; call pstop(1, "unknown event type")
    end select
  end function get_code
 
  function get_str(this) result(str)
    class(particleeventtype), intent(in) :: this
    character(len=:), allocatable :: str
 
    select type (this)
    type is (releaseeventtype); str = "released"
    type is (cellexiteventtype); str = "exited cell"
    type is (timestepeventtype); str = "completed timestep"
    type is (terminationeventtype); str = "terminated"
    type is (weaksinkeventtype); str = "exited weak sink"
    type is (usertimeeventtype); str = "user-specified tracking time"
    class default; call pstop(1, "unknown event type")
    end select
  end function get_str
 
end module particleeventmodule