LinearAlgebraUtils.f90

Go to the documentation of this file.

module linearalgebrautilsmodule
  use kindmodule, only: dp, i4b
 
  implicit none
  private
 
  public :: eye, outer_product, cross_product
 
contains
 
  pure function eye(n) result(A)
    ! -- dummy
    integer(I4B), intent(in) :: n
    real(dp), dimension(:, :), allocatable :: a
    ! -- locals
    integer(I4B) :: i
 
    allocate (a(n, n))
    a = 0.0_dp
    do i = 1, n
      a(i, i) = 1.0_dp
    end do
  end function eye
 
  pure function outer_product(A, B) result(AB)
    ! -- dummy
    real(dp), intent(in) :: a(:), b(:)
    real(dp) :: ab(size(a), size(b))
    ! -- locals
    integer :: na, nb
 
    na = size(a)
    nb = size(b)
 
    ab = spread(source=a, dim=2, ncopies=nb) * &
         spread(source=b, dim=1, ncopies=na)
  end function outer_product
 
  function cross_product(a, b) result(c)
    ! -- return
    real(dp), dimension(3) :: c
    ! -- dummy
    real(dp), dimension(3), intent(in) :: a
    real(dp), dimension(3), intent(in) :: b
 
    c(1) = a(2) * b(3) - a(3) * b(2)
    c(2) = a(3) * b(1) - a(1) * b(3)
    c(3) = a(1) * b(2) - a(2) * b(1)
  end function cross_product
 
end module linearalgebrautilsmodule